Source:Start Adventure

From Eamon Wiki
Jump to navigation Jump to search
This page is a verbatim reproduction of original source material and should not be edited except for maintenance.
Description

The Applesoft BASIC source code of the Eamon utility program Start Adventure (also called Adventure Only).

Source

EAG Utilities Disk

Date

c. 1984

Author

John Nelson

License

The use of this item is permitted on the grounds that it's free or in the public domain.

1  REM      ADVENTURE ONLY
2  REM      BY JOHN NELSON
3  REM  
4  REM   THIS PROGRAM ALLOWS YOU TO GO ON AN ADVENTURE WITHOUT USING THE MAIN HALL. YOU MUST RETURN TO THE SAME DISKETTE YOU CAME FROM
5  REM 
6  REM 
8  HOME : VTAB 6: PRINT "INSERT DISKETTE WITH CHARACTER DESIRED": PRINT : PRINT "     AND PRESS ANY KEY TO CONTINUE...";: POKE  - 16368,0: GET A$: PRINT 
10 DK$ =  CHR$ (4)
15  PRINT DK$"OPEN CHARACTERS,L150": PRINT DK$"READ CHARACTERS,R0": INPUT NC: PRINT DK$
20  INPUT "NAME OF ADVENTURER:";NA$: IF NA$ = "?" THEN 500
25  FOR REC = 1 TO NC: PRINT DK$"READ CHARACTERS,R";REC: INPUT N$
30  IF N$ <  > NA$ THEN  NEXT : PRINT DK$: PRINT "THAT CHARACTER IS NOT HERE.": PRINT "TRY AGAIN.": GOTO 20
50  PRINT DK$;"READ CHARACTERS,R";REC: INPUT NAME$: INPUT HD,AG,CH: FOR X = 1 TO 4: INPUT SA%(X): NEXT : FOR X = 1 TO 5: INPUT WA%(X): NEXT : INPUT AE
60  INPUT SEX$
70  INPUT GOLD,BANK: INPUT AC: FOR W = 1 TO 4: INPUT WNAME$(W),WTYPE%(W),WODDS%(W),WDICE%(W),WSIDES%(W): NEXT W: PRINT DK$;"CLOSE"
100  HOME : PRINT "INSERT ADVENTURE DISKETTE INTO DRIVE 1": PRINT : PRINT "     AND PRESS ANY KEY TO CONTINUE"
110  GOTO 1000
200  PRINT NAME$: PRINT HD: PRINT AG: PRINT CH: FOR X = 1 TO 4: PRINT SA%(X): NEXT : FOR X = 1 TO 5: PRINT WA%(X): NEXT : PRINT AE: PRINT SEX$
210  PRINT GOLD: PRINT BANK: PRINT AC: FOR W = 1 TO 4: PRINT WNAME$(W): PRINT WTYPE%(W): PRINT WOODS%(W): PRINT WDICE%(W): PRINT WSIDES%(W): NEXT W
220  RETURN 
500  REM  >> LIST NAMES
510  FOR R = 1 TO NC: PRINT DK$"READ CHARACTERS,R";R: INPUT X$
520  PRINT R;". ";X$: NEXT : PRINT DK$: GOTO 20
1000  REM 
1020  GET A$
1030  PRINT 
1040  PRINT DK$;"OPEN EAMON.NAME": PRINT DK$;"READ EAMON.NAME": INPUT ADNAME$: PRINT DK$;"CLOSE"
1050  HOME : VTAB 5: PRINT "YOU ARE ABOUT TO ADVENTURE IN": PRINT : INVERSE : PRINT ADNAME$: NORMAL : PRINT : PRINT 
1060  PRINT DK$;"OPEN FRESH MEAT": PRINT DK$;"WRITE FRESH MEAT": PRINT REC: GOSUB 200: PRINT DK$;"CLOSE": PRINT DK$;"RUN ";ADNAME$