Source:Change Eamon Name

This page is a verbatim reproduction of original source material and should not be edited except for maintenance.
Description	The Applesoft BASIC source code of the Eamon utility program Change Eamon Name, originally included on the Eamon Utilities I disk and later on the EAG Utilities Disk.
Source	EAG Utilities Disk
Date	c. 1984, modified 19 February 1996
Author	John Nelson
License	The use of this item is permitted on the grounds that it's free or in the public domain.

1  REM    RENAME EAMON ADVENTURE
2  REM       BY JOHN NELSON
3  REM 
4  REM   THIS PROGRAM WILL RENAME
		 ANY 6.0 ADVENTURE

5  REM 
6  REM 
7  REM  2/19/96
50  HOME : VTAB 6: PRINT "  INSERT EAMON ADVENTURE DISKETTE AND ": PRINT : PRINT  SPC( 12);"PRESS ANY KEY...";: POKE  - 16368,0: GET A$: PRINT 
60 D$ =  CHR$ (4)
65  ONERR  GOTO 50
70  PRINT D$"OPEN EAMON.NAME"
75 ND$ = "6"
80  PRINT D$"READ EAMON.NAME": INPUT ADV$
85  ONERR  GOTO 100
90  INPUT ND$
100  PRINT D$"CLOSE"
110  HOME : VTAB 6: PRINT "  OLD ADVENTURE NAME IS ...": PRINT 
120  PRINT "       ";: INVERSE : PRINT ADVNAM$: NORMAL : PRINT 
130  PRINT : PRINT : INPUT "NEW NAME:";NAM$
140  INPUT "AUTHOR NAME:";AU$
160  INPUT "ADVENTURE #";NUM$: IF  VAL (NUM$) < 2 OR  VAL (NUM$) > 254 THEN  VTAB  PEEK (37): CALL  - 958: GOTO 160
180 NUM =  VAL (NUM$)
1000  ONERR  GOTO 1500
1040  PRINT D$"UNLOCK EAMON.NAME"
1050  PRINT D$"DELETE EAMON.NAME"
1100  PRINT D$"OPEN EAMON.NAME"
1150  PRINT D$"WRITE EAMON.NAME"
1200  PRINT NAM$: PRINT ND$: PRINT "6.0"
1250  PRINT D$"CLOSE"
1300  PRINT D$"RENAME ";ADVNAM$;",";NAM$
1350  PRINT D$;"OPEN TEMP": PRINT D$;"WRITE TEMP": PRINT "LOAD EAMON ADVENTURE #";NUM: PRINT "0 A$="; CHR$ (34);NAM$; CHR$ (34);":A2$="; CHR$ (34);AU$; CHR$ (34);":NUM=";NUM
1360  PRINT "UNLOCK EAMON ADVENTURE #";NUM: PRINT "SAVE EAMON ADVENTURE #";NUM: PRINT "LOCK EAMON ADVENTURE #";NUM: PRINT "DELETE TEMP"
1370  PRINT D$;"CLOSE"
1400  PRINT "PROCESSING COMPLETED"
1450  PRINT : PRINT "YOU SHOULD SEE SEVERAL PROMPTS.": PRINT "THIS IS NORMAL."
1460  PRINT D$;"EXEC TEMP"
1470  END 
1500  REM  === ERROR ===
1550 ERR =  PEEK (222): IF ERR = 10 THEN 1700
1600  IF ERR = 6 THEN  PRINT : PRINT "FILE NOT FOUND. TERMINATING.": GOTO 1850
1650  PRINT "UNABLE TO COMPLETE. ERROR CODE = ";ERR: PRINT "NO CHANGE MADE": GOTO 1850
1700  PRINT : PRINT "FILE IS LOCKED. IF YOU WISH TO CHANGE ITANYWAY, PRESS 'C' ...";
1750  GET A$: PRINT : IF A$ <  > "C" THEN  PRINT : PRINT "NO CHANGES MADE.": GOTO 1850
1800  PRINT D$;"UNLOCK EAMON.NAME": GOTO 1050
1850  REM  === DONE ===
1900  PRINT "PROCESSING COMPLETED."
1950  END