Source:Quicky Room Print

From Eamon Wiki
Jump to navigation Jump to search
This page is a verbatim reproduction of original source material and should not be edited except for maintenance.
Description

The Applesoft BASIC source code of the Eamon utility program Quicky Room Print.

Source

EAG Utilities Disk

Date

13 November 1985

Author

John Nelson

License

The use of this item is permitted on the grounds that it's free or in the public domain.

0  REM         EAMON
1  REM    QUICKY ROOM PRINT
2  REM      BY JOHN NELSON
3  REM 
4  REM   
5  REM 
6  REM 
9  REM  REV. 11-13-85
10 D$ =  CHR$ (4)
20  ONERR  GOTO 40
40  HOME : VTAB 6: PRINT "  INSERT EAMON ADVENTURE DISKETTE AND": PRINT : PRINT  SPC( 10);"PRESS ANY KEY TO CONTINUE ...";: GET A$: PRINT 
50  HOME : VTAB 6: PRINT "DO YOU WANT PRINTER OUTPUT (Y/N):";
60  GET A$: IF A$ <  > "Y" AND A$ <  > "N" THEN 60
70  PRINT A$:PRT = (A$ = "Y"): IF  NOT PRT THEN 92
75  PRINT : PRINT "WHAT SLOT IS PRINTER IN (1-7):";
80  GET A$: IF A$ < "1" OR A$ > "7" THEN 80
90  PRINT A$:PS =  VAL (A$)
92  ONERR  GOTO 800
94  PRINT D$;"OPEN EAMON.NAME": PRINT D$;"READ EAMON.NAME": INPUT DUNGN$: INPUT DR$: PRINT D$;"CLOSE"
96  POKE 216,0
98 ND =  VAL (DR$)
100  PRINT D$"OPEN EAMON.ROOM NAMES,L64": PRINT D$"OPEN EAMON.ROOMS,L64": PRINT D$"OPEN EAMON.DESC,L256"
200  PRINT D$"READ EAMON.DESC,R0": INPUT NR,NA,NE,NM: PRINT D$"CLOSE EAMON.DESC"
300  IF PRT THEN  PRINT D$"PR#";PS
350  FOR X = 1 TO ND: READ D$(X): NEXT 
375  HOME 
400  FOR R = 1 TO NR: PRINT D$"READ EAMON.ROOM NAMES,R";R: INPUT N$: PRINT D$"READ EAMON.ROOMS,R";R: FOR D = 1 TO ND: INPUT DR%(D): NEXT 
450  PRINT D$
500  PRINT "ROOM ";R;":";N$: FOR D = 1 TO ND: IF DR%(D) <  > 0 THEN  PRINT D$(D);":"; SPC( 15 -  LEN (D$(D)) -  LEN ( STR$ (DR%(D))));DR%(D): IF  NOT PRT THEN  IF  PEEK (37) > 20 THEN  GOSUB 900
550  NEXT : PRINT 
600  NEXT :
700  PRINT D$"PR#0": PRINT D$"CLOSE": END 
800 ND = 6: POKE 216,0: GOTO 100
900  INVERSE : PRINT "      PRESS ANY KEY TO CONTINUE      ";: GET A$: PRINT : NORMAL : HOME : RETURN 
1000  DATA    NORTH,SOUTH,EAST,WEST,UP,DOWN,NORTHEAST,NORTHWEST,SOUTHEAST,SOUTHWEST