Source:Dungeon Init 7.1

This page is a verbatim reproduction of original source material and should not be edited except for maintenance.
Description	The Applesoft BASIC source code of the Eamon utility program Dungeon Init 7.1, part of the Eamon Dungeon Designer.
Source	Eamon Dungeon Designer version 7.1
Date	3 November 1988
Author	Donald Brown, John Nelson, Tom Zuchowski
License	The use of this item is permitted on the grounds that it's free or in the public domain.

0 D$ =  CHR$ (4):C3$ =  CHR$ (34): PRINT  CHR$ (21): GOTO 100
5  ONERR  GOTO 9
6 D$ =  CHR$ (4): PRINT D$"VERIFY GAME.PTRS": PRINT D$"RUN MAIN PGM"
9  POKE 216,0
10 D$ =  CHR$ (4): PRINT  CHR$ (21): TEXT : HOME : INVERSE 
20 S$ = "****************************************": PRINT S$; SPC( 60 -  LEN (AN$) / 2);AN$; SPC( 60): HTAB 1: PRINT S$: NORMAL 
30  PRINT  TAB( 11);"EAMON ADVENTURE #";NU: PRINT : PRINT S$
40  PRINT "THE EAMON GAMING SYSTEM WAS DEVELOPED        BY DON BROWN & JOHN NELSON": PRINT : PRINT AN$;" WAS": PRINT "    WRITTEN BY ";A2$
50  PRINT : PRINT : PRINT "TO RUN THIS ADVENTURE, YOU MUST BOOT      FROM THE EAMON MASTER DISKETTE.": PRINT 
60  END 
100  PRINT D$"BLOAD EAMON 7.1 SEARCH ROUTINE,A$5000"
120  HOME : HTAB 12: INVERSE : PRINT "*** WARNING ***": NORMAL : VTAB 6: PRINT "INSERT A NEW (BLANK) DISKETTE BEFORE    PROCEEDING!": VTAB 9: PRINT "PRESS 'C' WHEN READY ...";
130  POKE  - 16368,0: GET A$: IF A$ <  > "C" AND A$ <  > "c" THEN 130
140  PRINT A$: ONERR  GOTO 200
150 OP$ = D$ + "OPEN":WR$ = D$ + "WRITE":CL$ = D$ + "CLOSE":EA$ = OP$ + "EAMON"
160  PRINT D$;"CATALOG": PRINT : PRINT "IS IT OKAY TO INITIALIZE THIS DISKETTE?": PRINT : PRINT "  ENTER Y/N ";
170  POKE  - 16368,0: GET A$: IF  ASC (A$) > 96 THEN A$ =  CHR$ ( ASC (A$) - 32)
180  IF A$ <  > "Y" AND A$ <  > "N" THEN 170
190  PRINT A$: IF A$ = "N" THEN 100
200  REM   === GET INFORMATION
210  POKE 216,0
220  HOME : HTAB 12: PRINT "EAMON DUNGEON INIT": HTAB 8: PRINT "BY DON BROWN & JOHN NELSON": HTAB 8: PRINT "V7.1 MODS BY TOM ZUCHOWSKI"
230  VTAB 8: PRINT "NAME OF ADVENTURE (MAX. 25 CHARACTERS)": PRINT : PRINT " ";: INVERSE : PRINT  SPC( 25);
240  HTAB 5: INPUT ":";AN$: IF AN$ < "A" OR AN$ > "ZZZZ" OR  LEN (AN$) > 25 THEN 240
250  HOME : NORMAL : HTAB ((40 -  LEN (AN$)) / 2) + 1: INVERSE : PRINT AN$: NORMAL 
300  VTAB 5: PRINT "AUTHOR NAME (MAX 25 CHARACTERS)": INPUT A2$: IF  LEN (A2$) > 25 THEN 300
400  VTAB 7: INPUT "ADVENTURE NUMBER: ";A3$:NU =  VAL (A3$): IF NU <  >  INT (NU) OR NU < 0 OR NU > 999 OR  STR$ (NU) <  > A3$ THEN 400
500  VTAB 10:RL = 38: PRINT "LENGTH OF: (MIN 10 : MAX 80)"
510  INPUT "  ROOM NAMES (DEFAULT 38): ";A$: IF A$ = "" THEN 530
520 RL =  ABS ( INT ( VAL (A$))): IF RL < 10 OR RL > 80 THEN 500
530  VTAB 12:LR = RL + 34:ML = 30: INPUT "  MONSTER NAMES (DEFAULT 30): ";A$: IF A$ = "" THEN 550
540 ML =  ABS ( INT ( VAL (A$))): IF ML < 10 OR ML > 80 THEN 530
550  VTAB 13:LM = ML + 62:AL = 30: INPUT "  ARTIFACT NAMES (DEFAULT 30): ";A$: IF A$ = "" THEN 570
560 AL =  ABS ( INT ( VAL (A$))): IF AL < 10 OR AL > 80 THEN 550
570  VTAB 17:LA = AL + 42: PRINT "NAME LENGTHS:": PRINT "  ROOMS......";RL: PRINT "  MONSTERS...";ML: PRINT "  ARTIFACTS..";AL
580  VTAB 23: PRINT "OK? (Y/N)";
590  GET A$: IF A$ = "N" OR A$ = "n" THEN  PRINT : GOTO 500
600  IF A$ <  > "Y" AND A$ <  > "y" THEN 590
700  PRINT : PRINT D$;"INIT EAMON ADVENTURE #";NU
710  PRINT OP$" EXEC": PRINT WR$" EXEC"
720  PRINT "0 AN$="C3$AN$C3$":NU="NU":A2$="C3$A2$C3$
730  PRINT "DEL 100,1000"
740  PRINT "DELETE EAMON ADVENTURE #";NU: PRINT "SAVE EAMON ADVENTURE #";NU
750  PRINT "20 PRINT D$"C3$"RENAME EXEC,SAVE ";AN$;" HERE
760  PRINT "30 PRINT "C3$"PUT DESIGN DISK IN DRIVE NOW"C3$";
770  PRINT "40 POKE -16368,0: GET PT$: PRINT: ONERR GOTO 60
780  PRINT "50 NORMAL: PRINT D$"C3$"RUN EAMON DUNGEON DESIGNER 7.1
790  PRINT "RUN 10
800  PRINT OP$" LAST UPDATE:": PRINT CL$
810  PRINT EA$".NAME": PRINT WR$" EAMON.NAME"
820  PRINT AN$: PRINT 6: PRINT "7.1": PRINT CL$
830  PRINT EA$".ROOMS": PRINT EA$".MONSTERS"
840  PRINT EA$".ARTIFACTS": PRINT CL$
850  PRINT EA$".DESC": PRINT WR$" EAMON.DESC"
860  PRINT 0: PRINT 0: PRINT 0: PRINT 0: PRINT LR: PRINT LM: PRINT LA
870  PRINT CL$
880  PRINT D$"BSAVE EAMON 7.1 SEARCH ROUTINE,A$5000,L$11B"
890  PRINT D$;"EXEC EXEC": GOTO 10
900  REM DUNGEON INIT 7.1
910  REM 11/3/88
920  REM EAMON ADVENTURER'S GUILD
930  REM 7625 HAWKHAVEN DR.
940  REM CLEMMONS, NC 27012